path: root/default.nix

{ pkgs }:
self: super:
let
  default-derivation = { pname, version-prefix, version, sha256 }:
    pkgs.stdenv.mkDerivation rec {
      inherit pname version;

      src = fetchTarball {
        url =
          "https://git.euandreh.xyz/${pname}/snapshot/${pname}-${version-prefix}${version}.tar.gz";
        inherit sha256;
      };
      makeFlags = [
        # This shouldn't be necessary, but
        # the `stdenv.mkDerivation' environment doesn't provide a c99 variable
        "CC=cc"
      ];

      meta = with pkgs.lib; {
        description = readFile "${src}/description";
        longDescription = readFile "${src}/long-description";
        homepage = "https://${pname}.euandreh.xyz";
        changelog = "https://${pname}.euandreh.xyz/CHANGELOG.html";
        downloadPage = "https://${pname}.euandreh.xyz/#releases";
        license = licenses.agpl3;
        platforms = platforms.unix;
      };
    };
in {
  xyz-euandreh = {
    remembering = default-derivation {
      pname = "remembering";
      version-prefix = "";
      version = "cca66c6f53e8bce857faae88368c0b07e6ace9e1";
      sha256 = "0bpm73hvpk6x3vs2lkp0kjnfdyb5hq3spl0kzpq0wwmz2ilcvghh";
    };
    autoqemu = default-derivation {
      pname = "autoqemu";
      version-prefix = "";
      version = "5c44e0d0fa46ccd35c28e48849fcd5153fe41e5a";
      sha256 = "0izyp4ck618c10hr0n3365xdfgnp8vd3pwz147hanh0h3f0wmnj9";
    };
  };
}