path: root/etc/guix/home.scm

(use-modules
  ((ice-9 textual-ports) #:prefix textual-ports:)
  ((guix licenses) #:prefix licenses:)
  ((xyz euandreh heredoc) #:prefix heredoc:)
  (gnu)
  (gnu home)
  (gnu home services)
  (gnu home services mcron)
  (gnu home services shells)
  (gnu home services shepherd)
  (gnu home services syncthing)
  (gnu home services xdg)
  (guix build-system cmake)
  (guix build-system gnu)
  (guix build-system pyproject)
  (guix build-system python)
  (guix build-system perl)
  (guix build-system trivial)
  (guix download)
  (guix git-download)
  (guix packages)
  (guix utils))
(use-package-modules
  freedesktop
  messaging
  python-build
  wm
  xdisorg)
(heredoc:enable-syntax)



;; See:
;; https://github.com/NixOS/nixpkgs/issues/256704#issuecomment-1731626031
(define tdlib@1.8.4
  (package
    (inherit tdlib)
    (version "1.8.4")
    (source
      (origin
        (method git-fetch)
        (uri
          (git-reference
            (url "https://github.com/tdlib/td")
            (commit "7eabd8ca60de025e45e99d4e5edd39f4ebd9467e")))
        (file-name
          (git-file-name "tdlib" version))
        (sha256
          (base32 "1chs0ibghjj275v9arsn3k68ppblpm7ysqk0za9kya5vdnldlld5"))))))

(define python-telegram
  (package
    (name "python-telegram")
    (version "0.15.0")
    (source
      (origin
        (method url-fetch)
        (uri
          (pypi-uri name version))
        (sha256
          (base32 "0w61z0915mixxkcvwk22az032j3y46gkg8sadi5fqqb04li8vb9m"))))
    (build-system pyproject-build-system)
    (arguments
      (list
       #:phases
       #~(modify-phases %standard-phases
           (add-after 'unpack 'unvendor
             (lambda _
               (delete-file-recursively "telegram/lib/")))
           (add-after 'unvendor 'fix-find-library
             (lambda _
               (substitute* "telegram/tdjson.py"
                 (("= _get_tdjson_lib_path\\(\\)")
                  (string-append
                   "= \""
                   #$(this-package-input "tdlib")
                   "/lib/libtdjson.so\""))))))))
    (inputs
      (list
       tdlib@1.8.4))
    (home-page "https://github.com/alexander-akhmetov/python-telegram")
    (synopsis "Python library to help you build your own Telegram clients")
    (description #"-
      Python API for the @url{https://github.com/tdlib/td, tdlib} library.  It
      helps you build your own Telegram clients."#)
    (license licenses:expat)))

(define tg
  (package
    (name "tg")
    (version "0.19.0")
    (source
      (origin
        (method url-fetch)
        (uri
          (pypi-uri name version))
        (sha256
          (base32 "1jv9npas46pwl7v31xi7rlgm7bri3ydwqqq6wpgi13pp3byx46ig"))))
    (build-system pyproject-build-system)
    (arguments
      (list
       #:tests? #f  ; no tests
       #:phases
       #~(modify-phases %standard-phases
           (add-after 'unpack 'fix-some-hardcoded-strings
             (lambda _
               (substitute* "tg/config.py"
                 (("CONFIG_DIR = .*")
                   "CONFIG_DIR = (os.getenv('XDG_CONFIG_HOME') or os.getenv('HOME') + '/.config') + '/tg'\n")
                 (("FILES_DIR = .*")
                   "FILES_DIR = (os.getenv('XDG_CACHE_HOME') or os.getenv('HOME') + '/.cache') + '/tg'\n")
                 (("LOG_PATH = .*")
                   "LOG_PATH = (os.getenv('XDG_DATA_HOME') or os.getenv('HOME') + '/.local/share') + '/tg'\n")
                 (("DOWNLOAD_DIR = .*")
                   "DOWNLOAD_DIR = os.getenv('HOME') + '/Downloads/'\n")
                 (("API_ID = .*")
                   "API_ID   = os.getenv(\"TG_API_ID\")\n")
                 (("API_HASH = .*")
                   "API_HASH = os.getenv(\"TG_API_HASH\")\n")
                 (("NOTIFY_CMD = .*")
                   "NOTIFY_CMD = \"notify-send -a tg -i {icon_path} {title} '{msg}'\"\n")
                 (("LONG_MSG_CMD = .*")
                   "LONG_MSG_CMD = \"vi {file_path}\"\n")))))))
    (native-inputs
      (list
       python-poetry-core))
    (propagated-inputs
      (list
       python-telegram))
    (home-page "https://github.com/paul-nameless/tg")
    (synopsis "Terminal Telegram client")
    (description "TUI client for Telegram with vi-like bindings.")
    (license licenses:unlicense)))


(define (slurp name)
  (string-trim-both
   (call-with-input-file
    name
    textual-ports:get-string-all)))

(define (script name content)
  (package
    (name name)
    (version "latest")
    (source #f)
    (build-system trivial-build-system)
    (arguments
      `(#:modules ((guix build utils))
        #:builder
        (begin
          (use-modules (guix build utils))
          (let* ((bin (string-append %output "/bin"))
                 (prog (string-append bin "/" ,name)))
            (mkdir-p bin)
            (call-with-output-file prog
              (lambda (port)
                (format port "~a" ,content)))
            (chmod prog #o755)))))
    (home-page "")
    (synopsis "")
    (description "")
    (license #f)))

(define cronjobs
  (list
   #~(job "0 0 * * *" "cronjob check")
   #~(job "0 1 * * *" "cronjob backup -q cron")
   #~(job "0 2 * * 0" "cronjob gc")
   #~(job "0 3 * * *" "cronjob reconfigure -U")))

(define (home-service name package bin)
  (service-type
    (name name)
    (extensions
      (list
       (service-extension home-shepherd-service-type
         (lambda _
           (list
            (shepherd-service
              (provision (list name))
              (documentation
                (format #f "Shepherd service that manages ~a." name))
              (start
                #~(make-forkexec-constructor
                   (list #$(file-append package bin))))
              (stop #~(make-kill-destructor))))))
       (service-extension home-profile-service-type
         (lambda _ (list package)))))
    (default-value '())
    (description
      (format #f
       #"-
         Service that runs ~a as a daemon under Shepherd.

         It has no configuration."#
       name))))

(define xdg-prefix "$HOME/.usr")
(define (xdg path)
  (string-append xdg-prefix "/" path))

(home-environment
  (packages
    (append
     (map (compose list specification->package+output symbol->string)
          '(nss-certs
            nss:bin
            glibc-locales
            bash
            coreutils
            findutils
            diffutils
            time
            grep
            sed
            tar
            gawk
            bc

            man-pages
            man-pages-posix

            bash-completion


            ;; amber
            gperf
            bison
            gdb
            git
            git:send-email
            git:gui
            git-open
            git-remote-gcrypt
            mercurial
            fossil
            darcs
            cssc
            rcs
            cvs
            subversion
            quilt

            ;; urubu
            gperftools

            ;; venci
            ncurses
            ncurses:doc
            bdb
            nvi
            vis

            ;; lixo
            meson
            ninja
            flex
            gettext
            libelf
            sharutils
            libomp
            doxygen
            unzip
            dvd+rw-tools
            xorriso

            ;; refs
            universal-ctags
            global
            cscope

            ;; lime
            nasm

            ;; pilotis
            pandoc

            ;; papo
            sqlite

            ;; Arduino
            minicom
            python-pyserial


            wget
            tmux
            tmux-plugin-resurrect
            tmux-plugin-continuum
            texinfo
            gnupg
            rsync
            sshfs
            tree
            mailutils-sendmail
            pulseaudio
            password-store
            playerctl
            pinentry-gtk2
            diffoscope
            bmake
            make
            autoconf
            automake
            libtool
            pcre:out
            pcre:bin
            pcre:doc
            pcre:static
            pcre2
            avahi
            libgcrypt
            qbe
            cproc
            blktrace
            readline
            lokke
            pkg-config
            fzf
            blueman
            pavucontrol
            ledger
            gnuplot
            bind:utils
            netcat
            curl
            curl:doc
            xclip
            cloc
            strace
            file
            urlscan
            rlwrap
            direnv
            borg
            feh
            sox
            xset
            graphviz
            moreutils
            shellcheck
            lilypond
            groff
            groff:doc
            grap
            apl
            dyalog-apl
            ghostscript
            enscript
            jq
            units
            trash-cli
            lsof
            autojump
            qpdf
            perf-tools
            acl
            attr

            cryptsetup
            btrfs-progs

            clojure
            clojure-tools
            leiningen
            perl
            perl-json
            perl-commonmark
            perl-aliased
            perl-uri-escape
            clinfo
            pocl
            opencl-icd-loader
            pciutils
            usbutils
            python-pyopencl
            python-pandas
            python-scikit-learn
            python
            python-slixmpp
            python-unidecode
            python-pytest-cov
            python-pytest-xdist
            python-requests
            python-beautifulsoup4
            python-docx
            python-telegram-bot
            valgrind
            gcc-toolchain
            cppcheck
            clang
            tcc
            node
            xrandr
            arandr

            sbcl
            gcl
            ecl
            clisp
            ccl
            abcl

            tabbed
            st
            i3status
            scrot
            xmessage
            dmenu
            xmodmap
            brightnessctl
            xss-lock

            libnotify
            espeak-ng
            procps
            htop
            util-linux
            gzip
            xz
            psmisc
            less
            nano
            patch
            youtube-dl
            ripgrep

            vlc
            font-openmoji
            syncthing-gtk
            keepassxc
            cheese      ; webcam
            gpodder
            mate-calc
            telegram-desktop
            zathura
            zathura-djvu
            zathura-pdf-poppler
            zathura-ps
            transmission
            transmission:gui
            audacity
            quodlibet
            icedove
            netsurf
            firefox))
     (list tg
           (script "cronjob" (slurp (string-append (getenv "XDG_CONFIG_HOME")
                                                   "/sh/cronjob.sh"))))))
  (services
    (list
     (service (home-service 'clipmenu    clipmenu    "/bin/clipmenud"))
     (service (home-service 'dunst       dunst       "/bin/dunst"))
     (service (home-service 'poweralertd poweralertd "/bin/poweralertd"))
     (service home-xdg-base-directories-service-type
       (home-xdg-base-directories-configuration
         (cache-home  (xdg "var/cache"))
         (config-home (xdg "etc"))
         (data-home   (xdg "share"))
         (log-home    (xdg "var/log"))
         (state-home  (xdg "var/state"))))
     (service home-syncthing-service-type)
     (simple-service 'my-shell-profile home-shell-profile-service-type
       (list (plain-file
              "my-profile"
              (format #f
               #"-
                 export XDG_PREFIX="~a"
                 . "$XDG_CONFIG_HOME"/sh/rc"#
               xdg-prefix))))
     (service home-mcron-service-type
       (home-mcron-configuration
         (jobs cronjobs))))))