{ config, pkgs, ... }:

let
  envsubstConfiguration = {
    nextcloudTLD = "$NEXTCLOUD_TLD";
    gitTLD = "$GIT_TLD";
    letsencryptEmail = "$LETSENCRYPT_EMAIL";
    authorizedKey = "$AUTHORIZED_KEY";
    userPassword = "$USER_PASSWORD";
    nextcloudDatabaseUser = "$NEXTCLOUD_DATABASE_USER";
    nextcloudDatabasePassword = "$NEXTCLOUD_DATABASE_PASSWORD";
    nextcloudAdminUser = "$NEXTCLOUD_ADMIN_USER";
    nextcloudAdminPassword = "$NEXTCLOUD_ADMIN_PASSWORD";
    nextcloudTablePrefix = "$NEXTCLOUD_TABLE_PREFIX";
    gitRoot = "$GIT_ROOT";
    systemStateVersion = "$SYSTEM_STATE_VERSION";
  };
in {
  imports = [ ./hardware-configuration.nix ];

  boot.loader.grub = {
    enable = true;
    version = 2;
    device = "/dev/vda";
  };

  networking = {
    useDHCP = false;
    interfaces.ens3.useDHCP = true;
  };

  environment.systemPackages = with pkgs; [ vim git ];

  networking.firewall.allowedTCPPorts = [ 80 443 22 ];

  security.acme = {
    acceptTerms = true;
    email = envsubstConfiguration.letsencryptEmail;
  };

  services = {
    openssh = {
      enable = true;
      permitRootLogin = "no";
      passwordAuthentication = false;
    };

    nginx = {
      enable = true;
      recommendedGzipSettings = true;
      recommendedOptimisation = true;
      recommendedProxySettings = true;
      recommendedTlsSettings = true;
      virtualHosts = {
        "${envsubstConfiguration.nextcloudTLD}" = {
          forceSSL = true;
          enableACME = true;
        };
        "${envsubstConfiguration.gitTLD}" = {
          forceSSL = true;
          enableACME = true;
        };
      };
    };

    postgresql = {
      enable = true;
      ensureDatabases = [ "nextcloud" ];
      package = pkgs.postgresql_11;
      ensureUsers = [{
        name = "nextcloud";
        ensurePermissions."DATABASE nextcloud" = "ALL PRIVILEGES";
      }];
    };

    nextcloud = {
      enable = true;
      package = pkgs.nextcloud19;
      nginx.enable = true;
      hostName = envsubstConfiguration.nextcloudTLD;
      https = true;
      maxUploadSize = "4G";
      autoUpdateApps.enable = true;
      config = {
        overwriteProtocol = "https";
        dbtype = "pgsql";
        dbhost = "/run/postgresql";
        dbuser = envsubstConfiguration.nextcloudDatabaseUser;
        dbpass = envsubstConfiguration.nextcloudDatabasePassword;
        dbtableprefix = envsubstConfiguration.nextcloudTablePrefix;
        adminuser = envsubstConfiguration.nextcloudAdminUser;
        adminpass = envsubstConfiguration.nextcloudAdminPassword;
      };
    };
  };

  systemd.services."nextcloud-setup" = {
    requires = [ "postgresql.service" ];
    after = [ "postgresql.service" ];
  };

  users.extraUsers.andreh = {
    uid = 1000;
    isNormalUser = true;
    extraGroups = [ "wheel" ];
    password = envsubstConfiguration.userPassword;
    openssh.authorizedKeys.keys = [ envsubstConfiguration.authorizedKey ];
  };

  system.stateVersion = envsubstConfiguration.systemStateVersion;
}