{ config, pkgs, ... }:

let
  envsubstConfiguration = {
    TLD = "$TLD";
    nextcloudTLD = "$NEXTCLOUD_TLD";
    gitTLD = "$GIT_TLD";
    prosodyTLD = "$PROSODY_TLD";
    letsencryptEmail = "$LETSENCRYPT_EMAIL";
    authorizedKey = "$AUTHORIZED_KEY";
    userPassword = "$USER_PASSWORD";
    userName = "$USER_NAME";
    nextcloudDatabaseUser = "$NEXTCLOUD_DATABASE_USER";
    nextcloudDatabasePassword = "$NEXTCLOUD_DATABASE_PASSWORD";
    nextcloudAdminUser = "$NEXTCLOUD_ADMIN_USER";
    nextcloudAdminPassword = "$NEXTCLOUD_ADMIN_PASSWORD";
    nextcloudTablePrefix = "$NEXTCLOUD_TABLE_PREFIX";
    gitRoot = "$GIT_ROOT";
    gitPort = "$GIT_PORT";
    systemStateVersion = "$SYSTEM_STATE_VERSION";
    prosodyAdminUser = "$PROSODY_ADMIN_USER";
    prosodyMUCTLD = "$PROSODY_MUC_TLD";
    prosodyHTTPUploadTLD = "$PROSODY_HTTP_UPLOAD_TLD";
    prosodyPort = "$PROSODY_PORT";
  };
in {
  imports = [ ./hardware-configuration.nix ];

  boot.loader.grub = {
    enable = true;
    version = 2;
    device = "/dev/vda";
  };

  networking = {
    useDHCP = false;
    interfaces.ens3.useDHCP = true;
  };

  environment.systemPackages = with pkgs; [ vim git ];

  networking.firewall.allowedTCPPorts = [
    # SSH: OpenSSH
    22

    # HTTP and HTPPS: NGINX
    80
    443

    # XMPP: Prosody
    # https://prosody.im/doc/ports
    5000
    5222
    5269
    5280
    5281
    5347
    5582
  ];

  security.acme = {
    acceptTerms = true;
    email = envsubstConfiguration.letsencryptEmail;
    certs = {
      "${envsubstConfiguration.prosodyTLD}" = {
        webroot = "/var/www/${envsubstConfiguration.prosodyTLD}";
        email = envsubstConfiguration.letsencryptEmail;
        user = "prosody";
        extraDomains = {
          "${envsubstConfiguration.prosodyMUCTLD}" = null;
          "${envsubstConfiguration.prosodyHTTPUploadTLD}" = null;
        };
      };
    };
  };

  services = {
    openssh = {
      enable = true;
      permitRootLogin = "no";
      passwordAuthentication = false;
    };

    nginx = {
      enable = true;
      recommendedGzipSettings = true;
      recommendedOptimisation = true;
      recommendedProxySettings = true;
      recommendedTlsSettings = true;
      virtualHosts = {
        "${envsubstConfiguration.nextcloudTLD}" = {
          forceSSL = true;
          enableACME = true;
        };
        "${envsubstConfiguration.gitTLD}" = {
          forceSSL = true;
          enableACME = true;
          locations."/" = {
            proxyPass = "http://localhost:${envsubstConfiguration.gitPort}";
          };
        };
      };
    };

    postgresql = {
      enable = true;
      ensureDatabases = [ "nextcloud" ];
      package = pkgs.postgresql_11;
      ensureUsers = [{
        name = "nextcloud";
        ensurePermissions."DATABASE nextcloud" = "ALL PRIVILEGES";
      }];
    };

    nextcloud = {
      enable = true;
      package = pkgs.nextcloud19;
      nginx.enable = true;
      hostName = envsubstConfiguration.nextcloudTLD;
      https = true;
      maxUploadSize = "4G";
      autoUpdateApps.enable = true;
      config = {
        overwriteProtocol = "https";
        dbtype = "pgsql";
        dbhost = "/run/postgresql";
        dbuser = envsubstConfiguration.nextcloudDatabaseUser;
        dbpass = envsubstConfiguration.nextcloudDatabasePassword;
        dbtableprefix = envsubstConfiguration.nextcloudTablePrefix;
        adminuser = envsubstConfiguration.nextcloudAdminUser;
        adminpass = envsubstConfiguration.nextcloudAdminPassword;
      };
    };

    prosody = {
      enable = false;
      admins = [ envsubstConfiguration.prosodyAdminUser ];
      allowRegistration = true;
      ssl = {
        cert = "/var/lib/acme/${envsubstConfiguration.prosodyTLD}/fullchain.pem";
        key = "/var/lib/acme/${envsubstConfiguration.prosodyTLD}/key.pem";
      };
      virtualHosts = {
        "${envsubstConfiguration.prosodyTLD}" = {
          enabled = true;
          domain = "${envsubstConfiguration.prosodyTLD}";
          ssl = {
            cert = "/var/lib/acme/${envsubstConfiguration.prosodyTLD}/fullchain.pem";
            key = "/var/lib/acme/${envsubstConfiguration.prosodyTLD}/key.pem";
          };
        };
      };
    };

    lighttpd = {
      enable = true;
      port = pkgs.lib.toInt envsubstConfiguration.gitPort;
      cgit = {
        enable = true;
        subdir = "";
        configText = ''
          source-filter=${pkgs.cgit}/lib/cgit/filters/syntax-highlighting.py
          about-filter=${pkgs.cgit}/lib/cgit/filters/about-formatting.sh
          scan-path=${envsubstConfiguration.gitRoot}
        '';
      };
    };
  };

  systemd.services = {
    "nextcloud-setup" = {
      requires = [ "postgresql.service" ];
      after = [ "postgresql.service" ];
    };
    "lighttpd-cgit-install" = {
      enable = true;
      description = "Setup folders and permissions for lighttpd and cgit";
      wantedBy = [ "multi-user.target" ];
      script = ''
        mkdir -p ${envsubstConfiguration.gitRoot}
        chown -R ${envsubstConfiguration.userName}:lighttpd ${envsubstConfiguration.gitRoot}
        chmod -R 770 ${envsubstConfiguration.gitRoot}
      '';
      serviceConfig = {
        Type = "oneshot";
      };
    };
  };

  users.extraUsers."${envsubstConfiguration.userName}" = {
    uid = 1000;
    isNormalUser = true;
    extraGroups = [ "wheel" ];
    password = envsubstConfiguration.userPassword;
    openssh.authorizedKeys.keys = [ envsubstConfiguration.authorizedKey ];
  };

  system.stateVersion = envsubstConfiguration.systemStateVersion;
}