{ pkgs }: rec {
  md4c = pkgs.stdenv.mkDerivation rec {
    pname = "md4c";
    version = "release-0.4.6";
    src = pkgs.fetchFromGitHub {
      owner = "mity";
      repo = "md4c";
      rev = version;
      sha256 = "0km84rmcrczq4n87ryf3ffkfbjh4jim361pbld0z8wgp60rz08dh";
    };
    nativeBuildInputs = with pkgs; [ cmake ];
  };

  pymd4c = with pkgs.python3.pkgs;
    buildPythonPackage rec {
      pname = "pymd4c";
      version = "0.4.6.0b1";
      src = fetchPypi {
        inherit pname version;
        sha256 = "07s3arn85ri92im6x3ipljdmrxmpik7irs06i6lm17j1x6j9841d";
      };
      nativeBuildInputs = [ pkgs.pkgconfig ];
      propagatedBuildInputs =
        [ md4c pkgs.python3Packages.cffi pkgs.python3Packages.pkgconfig ];

      preConfigure = ''
        export INCLUDE_DIR=${md4c}/include
        export LIB_DIR=${md4c}/lib
      '';
    };

  mdpo = with pkgs.python3.pkgs;
    buildPythonPackage rec {
      pname = "mdpo";
      version = "0.2.36";
      src = fetchPypi {
        inherit pname version;
        sha256 = "0gp8wi5c2x3yqslipvkm8m1wvnyji5g52v4195871dhb93kzyzv0";
      };
      propagatedBuildInputs = with pkgs.python3Packages; [ polib pymd4c ];
    };
}