let
  niv-sources = import ./nix/sources.nix;
  pkgs = import niv-sources.nixpkgs { };
  src = pkgs.nix-gitignore.gitignoreSource [ "!.git" ] ./.;
  utils-i18n = pkgs.callPackage ./utils-i18n.nix { };

  jekyllEnv = pkgs.bundlerEnv {
    name = "jekyll-env";
    gemfile = ./Gemfile;
    lockfile = ./Gemfile.lock;
    gemset = ./gemset.nix;
  };
  projectBuildInputs = with pkgs; [
    jekyllEnv

    perl
    graphviz
    nixfmt
    git
    shellcheck
    jq
    niv
    (hunspellWithDicts (with utils-i18n.dicts; [ en pt fr ]))
  ];
in rec {
  site = pkgs.stdenv.mkDerivation {
    inherit src;
    name = "website-site";
    phases = [ "unpackPhase" "buildPhase" ];
    buildInputs = [ jekyllEnv ];
    buildPhase = ''
      patchShebangs .
      jekyll build -d $out
    '';
  };
  test = pkgs.stdenv.mkDerivation {
    inherit src;
    name = "website-test";
    phases = [ "unpackPhase" "buildPhase" ];
    buildInputs = projectBuildInputs;
    buildPhase = ''
      patchShebangs .
      ./tests.sh
      touch $out
    '';
  };
  shell = pkgs.mkShell {
    name = "website-shell";
    buildInputs = projectBuildInputs;
    shellHook = ''
      echo 'Start a live server with:'
      echo '  jekyll serve --future --livereload'
    '';
  };
  publishScript = pkgs.writeShellScriptBin "publish.sh" ''
    set -euo pipefail
    SERVER_URL='root@euandre.org'
    REMOTE_PATH='/home/user-data/www/default/'
    OUT_DOCS='${site}'
    ${pkgs.openssh}/bin/ssh -o StrictHostKeyChecking=no "$SERVER_URL" rm -rf "$REMOTE_PATH/*"
    ${pkgs.rsync}/bin/rsync -avzP                                   \
                            --rsh="ssh -o StrictHostKeyChecking=no" \
                            "$OUT_DOCS/"                            \
                            "$SERVER_URL:$REMOTE_PATH"
  '';
}