let
  pkgs = import <nixpkgs> { };
in rec {
  utils = import ./utils.nix {
    pkgs = pkgs;
    src = pkgs.nix-gitignore.gitignoreSource [ ] ./.;
    baseName = "website";
  };
  jekyllEnv = pkgs.bundlerEnv {
    name = "jekyll-env";
    gemfile = ./Gemfile;
    lockfile = ./Gemfile.lock;
    gemset = ./gemset.nix;
  };
  subtasks = rec {
    hunspellCheck = utils.baseTask.overrideAttrs (baseAttrs: {
      name = "${baseAttrs.name}-hunspell";
      buildInputs = baseAttrs.buildInputs
        ++ [ (pkgs.hunspellWithDicts (with pkgs.hunspellDicts; [ en-us ])) ];
      buildPhase = ''
        patchShebangs .
        ./spelling/check-spelling.sh "${subtasks.docs}"
        touch $out
      '';
    });
    docs = utils.baseTask.overrideAttrs (baseAttrs: {
      name = "${baseAttrs.name}-docs";
      buildInputs = [ jekyllEnv ];
      buildPhase = ''
        mkdir $out
        jekyll build -d $out
      '';
    });
  };
  test = utils.test [
    utils.formatNix
    (utils.shellcheck null)
    (utils.fixme null)
    subtasks.hunspellCheck
  ];
  shell = pkgs.mkShell rec {
    name = "website-shell";
    buildInputs = [
      jekyllEnv
      (pkgs.hunspellWithDicts (with pkgs.hunspellDicts; [ en-us ]))
    ];
  };
  publishScript = utils.overwritingPublishScript {
    docsDerivation = subtasks.docs;
    overwrite = false;
  };
}